commit: e3f9a307704c2e2e1ce2a996690923c1b6bec41c
Author: Julien Roy <julien <AT> jroy <DOT> ca>
AuthorDate: Sat May 25 18:55:06 2024 +0000
Commit: Julien Roy <julien <AT> jroy <DOT> ca>
CommitDate: Sat May 25 18:55:06 2024 +0000
URL: https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=e3f9a307
dev-python/celery: add 5.4.0
Signed-off-by: Julien Roy <julien <AT> jroy.ca>
dev-python/celery/Manifest | 1 +
dev-python/celery/celery-5.4.0.ebuild | 88 +++++++++++++++++++++++++++++++++++
dev-python/celery/metadata.xml | 5 +-
3 files changed, 93 insertions(+), 1 deletion(-)
diff --git a/dev-python/celery/Manifest b/dev-python/celery/Manifest
index 8dcffe5f8..479de3b2a 100644
--- a/dev-python/celery/Manifest
+++ b/dev-python/celery/Manifest
@@ -1 +1,2 @@
DIST celery-5.3.6.gh.tar.gz 1563926 BLAKE2B
c5f86110f7907b8ae084354dafe4e26adb07702150658ddb60a85f58c3e80106aafb921150c78670d05c68c26f17ad1144b4142d6ec9b86e9c9cdb1b653baaa6
SHA512
529611c0d3bfcbfcc931e5d20cf89a4710a8d2e70639e5c2e991ba020c3c2402bfd38b7ef17ecfbc5fe493f046531094158e81b03610191c3af2b531cc913762
+DIST celery-5.4.0.gh.tar.gz 1589006 BLAKE2B
ca63fbd18552f6c345aac8cf8860b868263fcdf7c3836a99d31166fc3feb0087af1a403ff1f4e8f866277fbf7feafa1173691acb4549154d32c55759eae75bad
SHA512
e39ea88afb529aba14f621a9809c5e18ff1596754162069410249186b3f1512683fe67bb425994514b39fdea562b55ace89a16d57d614259269adf48427144ef
diff --git a/dev-python/celery/celery-5.4.0.ebuild
b/dev-python/celery/celery-5.4.0.ebuild
new file mode 100644
index 000000000..c1cc99a2e
--- /dev/null
+++ b/dev-python/celery/celery-5.4.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..12} )
+
+inherit bash-completion-r1 check-reqs distutils-r1 optfeature
+
+MY_PV="${PV/_beta/b}"
+DESCRIPTION="Asynchronous task queue/job queue based on distributed message
passing"
+HOMEPAGE="
+ https://pypi.org/project/celery/
+ https://github.com/celery/celery
+"
+SRC_URI="https://github.com/celery/celery/archive/v${MY_PV}.tar.gz ->
${P}.gh.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples"
+# Tests require a lot of dependencies that are not packaged for Gentoo
+RESTRICT="test"
+
+RDEPEND="
+ >=dev-python/billiard-3.6.4.0[${PYTHON_USEDEP}]
+ <dev-python/billiard-5.0.0[${PYTHON_USEDEP}]
+ dev-python/click[${PYTHON_USEDEP}]
+ dev-python/click-didyoumean[${PYTHON_USEDEP}]
+ dev-python/click-plugins[${PYTHON_USEDEP}]
+ dev-python/click-repl[${PYTHON_USEDEP}]
+ >=dev-python/python-dateutil-2.8.2[${PYTHON_USEDEP}]
+ >=dev-python/kombu-5.3.0_beta1[${PYTHON_USEDEP}]
+ <dev-python/kombu-6.0.0[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ dev-python/vine[${PYTHON_USEDEP}]
+
+ doc? (
+ dev-python/docutils[${PYTHON_USEDEP}]
+ >=dev-python/sphinx-celery-2.0.0[${PYTHON_USEDEP}]
+ >=dev-python/sphinx-click-2.5.0[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/sqlalchemy[${PYTHON_USEDEP}]
+ )
+"
+DEPEND="${RDEPEND}"
+
+CHECKREQS_MEMORY="2G"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs --no-autodoc
+
+pkg_setup() {
+ use test && check-reqs_pkg_setup
+}
+
+pkg_pretend() {
+ use test && check-reqs_pkg_pretend
+}
+
+python_install_all() {
+ # Main celeryd init.d and conf.d
+ newinitd "${FILESDIR}/celery.initd-r2" celery
+ newconfd "${FILESDIR}/celery.confd-r2" celery
+
+ if use examples; then
+ docinto examples
+ dodoc -r examples/.
+ docompress -x /usr/share/doc/${PF}/examples
+ fi
+
+ newbashcomp extra/bash-completion/celery.bash "${PN}"
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "msgpack support" dev-python/msgpack
+ optfeature "redis support" dev-python/redis-py
+ optfeature "auth support" dev-python/pyopenssl
+ optfeature "yaml support" dev-python/pyyaml
+ optfeature "memcache support" dev-python/pylibmc
+ optfeature "mongodb support" dev-python/pymongo
+ optfeature "sqlalchemy support" dev-python/sqlalchemy
+ optfeature "sqs support" dev-python/boto
+}
diff --git a/dev-python/celery/metadata.xml b/dev-python/celery/metadata.xml
index 5ca07e299..53e26926a 100644
--- a/dev-python/celery/metadata.xml
+++ b/dev-python/celery/metadata.xml
@@ -1,7 +1,10 @@
<?xml version='1.0' encoding='UTF-8'?>
<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd";>
<pkgmetadata>
- <!-- maintainer-needed -->
+ <maintainer type="person">
+ <name>Julien Roy</name>
+ <email>jul...@jroy.ca</email>
+ </maintainer>
<upstream>
<remote-id type="pypi">celery</remote-id>
<remote-id type="github">celery/celery</remote-id>
