commit: 786ad62b90414649f22814c5aaeaba8738295ac4
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 17 16:46:00 2024 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Nov 18 20:03:45 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=786ad62b
kde-plasma/libksysguard: set cap_sys_nice=ep on ksgrd_network_helper
Upstream commit 1bb5880f08e93e49017dfca6359b293a3bb6f5dc
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
.../libksysguard/libksysguard-6.2.3-r1.ebuild | 57 ++++++++++++++++++++++
1 file changed, 57 insertions(+)
diff --git a/kde-plasma/libksysguard/libksysguard-6.2.3-r1.ebuild
b/kde-plasma/libksysguard/libksysguard-6.2.3-r1.ebuild
new file mode 100644
index 000000000000..975ca0ee3c5c
--- /dev/null
+++ b/kde-plasma/libksysguard/libksysguard-6.2.3-r1.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=6.6.0
+QTMIN=6.7.2
+inherit ecm fcaps plasma.kde.org
+
+DESCRIPTION="Task management and system monitoring library"
+
+LICENSE="LGPL-2+"
+SLOT="6/9"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE=""
+
+RDEPEND="
+ dev-libs/libnl:3
+ >=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
+ >=dev-qt/qtdeclarative-${QTMIN}:6
+ >=kde-frameworks/kauth-${KFMIN}:6
+ >=kde-frameworks/kconfig-${KFMIN}:6[qml]
+ >=kde-frameworks/kcoreaddons-${KFMIN}:6
+ >=kde-frameworks/ki18n-${KFMIN}:6
+ >=kde-frameworks/knewstuff-${KFMIN}:6
+ >=kde-frameworks/kpackage-${KFMIN}:6
+ >=kde-frameworks/kservice-${KFMIN}:6
+ >=kde-frameworks/solid-${KFMIN}:6
+ net-libs/libpcap
+ sys-apps/lm-sensors:=
+ sys-libs/zlib
+"
+DEPEND="${RDEPEND}"
+
+# -m 0755 to avoid suid with USE="-filecaps"
+FILECAPS=( -m 0755 cap_sys_nice=ep usr/libexec/ksysguard/ksgrd_network_helper )
+
+src_configure() {
+ local mycmakeargs=(
+ -DCMAKE_DISABLE_FIND_PACKAGE_Libcap=ON
+ )
+ ecm_src_configure
+}
+
+src_test() {
+ # bugs 797898, 889942: flaky test
+ local myctestargs=(
+ -E "(sensortreemodeltest)"
+ )
+ LC_NUMERIC="C" ecm_src_test # bug 695514
+}
+
+pkg_postinst() {
+ ecm_pkg_postinst
+ fcaps_pkg_postinst
+}
