>Does anyone know how to force gdb to display an entire string
>instead of truncating while debugging?
This won't necessarily answer your question but,
FYI, gdb has a fully functional printf as well as data
manipulation capabilities, not to mention the ability to
define procedures and macros, etc. As an example, here
are some bleeding chunks ripped from the .gdbinit I put
together from a couple of projects ago...
define formattedSelector
set $selectorBits = $arg0
set $XXXXBits = $selectorBits & 0x0000ffff
set $slotBits = $selectorBits & 0x00ff0000
set $slotBits = $slotBits >> 8
set $slotBits = $slotBits >> 8
if ( $selectorBits & 0xff000000 )
printf "*%03d[%03d]", $XXXXBits, $slotBits
else
printf " %03d[%03d]", $XXXXBits, $slotBits
end
end
document formattedSelector
formattedSelector selectorValue
For example, displays the selector as "* 4[ 0]"
with the asterisk indicating a Redirect.
end
define showCommArray
set $limit = 0x20
printf "Assuming %03d slots\n", $limit
set $index = 0
set $lockXXXXlocal = lockXXXXlocal
printf "==========================================================\n"
printf " SLOT redirect next predecessor handoff readyFlag\n"
while ( $index < $limit )
printf "%03d[%03d] ", $lockXXXXlocal, $index
set $temp = localCAslot[ $index ].redirect
formattedSelector $temp
printf " "
set $temp = localCAslot[ $index ].next
formattedSelector $temp
printf " "
set $temp = localCAslot[ $index ].predecessor
formattedSelector $temp
set $temp = localCAslot[ $index ].handoff
if ( $temp == 0 )
set $temp = 0x3f
end
printf " %c ", $temp
set $temp = localCAslot[ $index ].readyFlag
formattedSelector $temp
printf "\n"
set $index = $index + 1
end
end
document showCommArray
Formats contents of all XXX communications slots
on current XX. Assumes remoteCAmappingIndexLimit,
lockXXXXlocal and localCAslot are visible.
end
**********************************************************
To unsubscribe from this list, send mail to
[EMAIL PROTECTED] with the following text in the
*body* (*not* the subject line) of the letter:
unsubscribe gnhlug
**********************************************************
