Re: [indoprog-vb] Cetak di printer POS EPSON TM-U220

[Andrie Baskara]

Nih Ada scripnya. Script ini bisa dipakai di printer lokal maupun jaringan. 
Copy di module aja, trus kalo mau cetak data tinggal ketikin CetakData 
"Tulisannya"

Semoga membantu

Option Explicit

Private Type DOCINFO
    pDocName As String
    pOutputFile As String
    pDatatype As String
End Type

Private Declare Function ClosePrinter Lib "winspool.drv" (ByVal _
         hPrinter As Long) As Long
Private Declare Function EndDocPrinter Lib "winspool.drv" (ByVal _
         hPrinter As Long) As Long
Private Declare Function EndPagePrinter Lib "winspool.drv" (ByVal _
         hPrinter As Long) As Long
Private Declare Function OpenPrinter Lib "winspool.drv" Alias _
         "OpenPrinterA" (ByVal pPrinterName As String, phPrinter As Long, _
          ByVal pDefault As Long) As Long
Private Declare Function StartDocPrinter Lib "winspool.drv" Alias _
         "StartDocPrinterA" (ByVal hPrinter As Long, ByVal Level As Long, _
         pDocInfo As DOCINFO) As Long
Private Declare Function StartPagePrinter Lib "winspool.drv" (ByVal _
         hPrinter As Long) As Long
Private Declare Function WritePrinter Lib "winspool.drv" (ByVal _
         hPrinter As Long, pBuf As Any, ByVal cdBuf As Long, _
         pcWritten As Long) As Long
Dim lhPrinter As Long
Sub OpenPrintingMode()
'Makasih Rekan Diony
    On Error GoTo hell
    Dim lreturn As Long
    Dim lDoc As Long
    Dim MyDocInfo As DOCINFO
    lreturn = OpenPrinter(Printer.DeviceName, lhPrinter, 0)
    If lreturn = 0 Then
        MsgBox "The Printer Name you typed wasn't recognized."
        Exit Sub
    End If
    MyDocInfo.pDocName = "Baskara"
    MyDocInfo.pOutputFile = vbNullString
    MyDocInfo.pDatatype = vbNullString
    lDoc = StartDocPrinter(lhPrinter, 1, MyDocInfo)
    Call StartPagePrinter(lhPrinter)
    Exit Sub
hell:
'PesanSalah
End Sub

Sub closePrintingMode()
    Dim lreturn As Integer
    lreturn = EndPagePrinter(lhPrinter)
    lreturn = EndDocPrinter(lhPrinter)
    lreturn = ClosePrinter(lhPrinter)
End Sub

Sub PrintThisLine(ByVal MyStr As String)
    Dim lreturn As Long
    Dim lpcWritten As Long
    Dim sWrittenData As String
    sWrittenData = MyStr & vbCrLf
    lreturn = WritePrinter(lhPrinter, ByVal sWrittenData, _
                Len(sWrittenData), lpcWritten)
End Sub

Public Sub CetakData(Datanya As String)
    OpenPrintingMode
    PrintThisLine Datanya
    closePrintingMode
End Sub








  ----- Original Message ----- 
  From: Achmad lukman 
  To: indoprog-vb@yahoogroups.com 
  Sent: Sunday, December 23, 2007 6:06 PM
  Subject: Re: [indoprog-vb] Cetak di printer POS EPSON TM-U220


  kalo ga salah, pake kode ASCII untuk output ke printer jenis itu dan 
sekaligus ngontrol laci uangnya... hehe.. sama...aku juga lagi cari nih 
sekarang. mungkin teman2 ada yang bisa bantu ..

  ---------------------------------
  Bergabunglah dengan orang-orang yang berwawasan, di bidang Anda di Yahoo! 
Answers

  [Non-text portions of this message have been removed]



   


[Non-text portions of this message have been removed]