buat modul ketik code berikut
Option Explicit
Public xserver
'API Structures
Type TIME_OF_DAY_INFO
tod_elapsed As Long
tod_msecs As Long
tod_hours As Long
tod_mins As Long
tod_secs As Long
tod_hunds As Long
tod_timezone As Long
tod_tinterval As Long
tod_day As Long
tod_month As Long
tod_year As Long
tod_weekday As Long
End Type
'NetAPI Calls
Public Declare Function NetRemoteTOD Lib "netapi32.dll" (yServer As Any,
pBuffer As Long) As Long
Private Declare Function NetApiBufferFree Lib "netapi32.dll" (ByVal pBuffer As
Long) As Long
'Kernel API Calls
Private Declare Sub CopyMem Lib "kernel32.dll" Alias "RtlMoveMemory" (pTo As
Any, uFrom As Any, ByVal lSize As Long)
Public Function GetRemoteTime(ServerName As String) As Date
Dim lpBuffer As Long
Dim t_struct As TIME_OF_DAY_INFO
Dim ret As Long
Dim bServer() As Byte
If Trim(ServerName) = "" Then
'Local machine
ret = NetRemoteTOD(vbNullString, lpBuffer)
Else
'Check the syntax of the ServerName string
If InStr(ServerName, "\\") = 1 Then
bServer = ServerName & vbNullChar
Else
bServer = "\\" & ServerName & vbNullChar
End If
ret = NetRemoteTOD(bServer(0), lpBuffer)
End If
CopyMem t_struct, ByVal lpBuffer, Len(t_struct)
If lpBuffer Then
Call NetApiBufferFree(lpBuffer)
End If
GetRemoteTime = DateSerial(t_struct.tod_year, t_struct.tod_month,
t_struct.tod_day) + TimeSerial(t_struct.tod_hours, t_struct.tod_mins -
t_struct.tod_timezone, t_struct.tod_secs)
End Function
dari form panggil
Private Sub Command3_Click()
xtglkel = Format$(GetRemoteTime(isi_nama_server_anda), "MM-dd-yyyy")
msgbox xtglkel
End Sub
--- In [email protected], "ianvirgo74" <ianvirg...@...> wrote:
>
> Salam para Vb
> Saya mau nanya neh gimana caranya kita bisa mendapatkan informasi tanggal dan
> waktu dari komputer lain dalam LAN.
> Kalo dalam mode dos saya bisa dapatkan tanggal dan jam dari komputer lain.
> cuma saya gak bisa membacanya dalam vb
>
> kalo dalam command prompt saya gunakan seperti ini :
> c:\net time \\server
> nah kalo dari itu saya dapat current time dan current time dari komputer yang
> saya namakan server
> cuma kalo hasilnya kita baca ke vb gimana caranya ya
> makasih atas info nya ya
>
