[jBoss-Dev] CVS update: manual/src/docs/docbook/htmlxtdocbook.xsl xtindex.xsl

[jBoss CVS Development]

  User: tobias  
  Date: 01/03/11 17:13:32

  Added:       src/docs/docbook/html xtdocbook.xsl xtindex.xsl
  Log:
  updated to newest version. Missed some files on last commit. Here they are.
  
  Revision  Changes    Path
  1.1                  manual/src/docs/docbook/html/xtdocbook.xsl
  
  Index: xtdocbook.xsl
  ===================================================================
  <?xml version='1.0'?>
  <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                  xmlns:doc="http://nwalsh.com/xsl/documentation/1.0"
                  exclude-result-prefixes="doc"
                  version='1.0'>
  
  <xsl:output method="html"
              encoding="ISO-8859-1"
              indent="no"/>
  
  <!-- ********************************************************************
       $Id: xtdocbook.xsl,v 1.1 2001/03/12 01:13:31 tobias Exp $
       ********************************************************************
  
       This file is part of the XSL DocBook Stylesheet distribution.
       See ../README or http://nwalsh.com/docbook/xsl/ for copyright
       and other information.
  
       ******************************************************************** -->
  
  <!-- ==================================================================== -->
  
  <xsl:include href="../VERSION"/>
  <xsl:include href="../lib/lib.xsl"/>
  <xsl:include href="../common/l10n.xsl"/>
  <xsl:include href="../common/common.xsl"/>
  <xsl:include href="autotoc.xsl"/>
  <xsl:include href="lists.xsl"/>
  <xsl:include href="callout.xsl"/>
  <xsl:include href="verbatim.xsl"/>
  <xsl:include href="graphics.xsl"/>
  <xsl:include href="xref.xsl"/>
  <xsl:include href="formal.xsl"/>
  <xsl:include href="table.xsl"/>
  <xsl:include href="sections.xsl"/>
  <xsl:include href="inline.xsl"/>
  <xsl:include href="footnote.xsl"/>
  <xsl:include href="html.xsl"/>
  <xsl:include href="info.xsl"/>
  <xsl:include href="keywords.xsl"/>
  <xsl:include href="division.xsl"/>
  <xsl:include href="toc.xsl"/>
  <xsl:include href="xtindex.xsl"/>
  <xsl:include href="refentry.xsl"/>
  <xsl:include href="math.xsl"/>
  <xsl:include href="admon.xsl"/>
  <xsl:include href="component.xsl"/>
  <xsl:include href="biblio.xsl"/>
  <xsl:include href="glossary.xsl"/>
  <xsl:include href="block.xsl"/>
  <xsl:include href="qandaset.xsl"/>
  <xsl:include href="synop.xsl"/>
  <xsl:include href="titlepage.xsl"/>
  <xsl:include href="titlepage.templates.xsl"/>
  <xsl:include href="param.xsl"/>
  <xsl:include href="pi.xsl"/>
  
  <!-- ==================================================================== -->
  
  <xsl:template match="*">
    <xsl:message>
      <xsl:text>No template matches </xsl:text>
      <xsl:value-of select="name(.)"/>
      <xsl:text>.</xsl:text>
    </xsl:message>
  
    <font color="red">
      <xsl:text>&lt;</xsl:text>
      <xsl:value-of select="name(.)"/>
      <xsl:text>&gt;</xsl:text>
      <xsl:apply-templates/>
      <xsl:text>&lt;/</xsl:text>
      <xsl:value-of select="name(.)"/>
      <xsl:text>&gt;</xsl:text>
    </font>
  </xsl:template>
  
  <xsl:template match="text()">
    <xsl:value-of select="."/>
  </xsl:template>
  
  <xsl:template name="head.content">
    <xsl:param name="node" select="."/>
    <xsl:variable name="info" select="($node/docinfo
                                       |$node/chapterinfo
                                       |$node/appendixinfo
                                       |$node/prefaceinfo
                                       |$node/bookinfo
                                       |$node/setinfo
                                       |$node/articleinfo
                                       |$node/artheader
                                       |$node/sect1info
                                       |$node/sect2info
                                       |$node/sect3info
                                       |$node/sect4info
                                       |$node/sect5info
                                       |$node/refsect1info
                                       |$node/refsect2info
                                       |$node/refsect3info
                                       |$node/bibliographyinfo
                                       |$node/glossaryinfo
                                       |$node/indexinfo
                                       |$node/refentryinfo
                                       |$node/partinfo
                                       |$node/referenceinfo)[1]"/>
  
    <title>
      <xsl:apply-templates select="$node" mode="title.ref">
        <xsl:with-param name="text-only" select="'1'"/>
      </xsl:apply-templates>
    </title>
  
    <xsl:if test="$html.stylesheet">
      <link rel="stylesheet"
            href="{$html.stylesheet}"
            type="{$html.stylesheet.type}"/>
    </xsl:if>
  
    <xsl:if test="$link.mailto.url != ''">
      <link rev="made"
            href="{$link.mailto.url}"/>
    </xsl:if>
  
    <xsl:if test="$html.base != ''">
      <base href="{$html.base}"/>
    </xsl:if>
  
    <meta name="generator" content="DocBook XSL Stylesheets V{$VERSION}"/>
  
    <xsl:apply-templates select="$info/keywordset" mode="html.header"/>
  </xsl:template>
  
  <xsl:template name="user.head.content">
    <xsl:param name="node" select="."/>
  </xsl:template>
  
  <xsl:template name="user.header.content">
    <xsl:param name="node" select="."/>
  </xsl:template>
  
  <xsl:template name="user.footer.content">
    <xsl:param name="node" select="."/>
  </xsl:template>
  
  <xsl:template match="/">
    <xsl:choose>
      <xsl:when test="$rootid != ''">
        <xsl:choose>
          <xsl:when test="count(id($rootid)) = 0">
            <xsl:message terminate="yes">
              <xsl:text>ID '</xsl:text>
              <xsl:value-of select="$rootid"/>
              <xsl:text>' not found in document.</xsl:text>
            </xsl:message>
          </xsl:when>
          <xsl:otherwise>
            <xsl:apply-templates select="id($rootid)" mode="process.root"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:when>
      <xsl:otherwise>
        <xsl:apply-templates select="/" mode="process.root"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
  
  <xsl:template match="*" mode="process.root">
    <xsl:variable name="doc" select="self::*"/>
    <html>
    <head>
      <xsl:call-template name="head.content">
        <xsl:with-param name="node" select="$doc"/>
      </xsl:call-template>
      <xsl:call-template name="user.head.content"/>
    </head>
    <body xsl:use-attribute-sets="body.attrs">
      <xsl:call-template name="user.header.content">
        <xsl:with-param name="node" select="$doc"/>
      </xsl:call-template>
      <xsl:apply-templates select="."/>
      <xsl:call-template name="user.footer.content">
        <xsl:with-param name="node" select="$doc"/>
      </xsl:call-template>
    </body>
    </html>
  </xsl:template>
  
  <!-- ==================================================================== -->
  
  </xsl:stylesheet>
  
  
  
  1.1                  manual/src/docs/docbook/html/xtindex.xsl
  
  Index: xtindex.xsl
  ===================================================================
  <?xml version='1.0'?>
  <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                  version='1.0'>
  
  <!-- ********************************************************************
       $Id: xtindex.xsl,v 1.1 2001/03/12 01:13:31 tobias Exp $
       ********************************************************************
  
       This file is part of the XSL DocBook Stylesheet distribution.
       See ../README or http://nwalsh.com/docbook/xsl/ for copyright
       and other information.
  
       ******************************************************************** -->
  
  <!-- ==================================================================== -->
  
  <xsl:template match="index|setindex">
    <!-- some implementations use completely empty index tags to indicate -->
    <!-- where an automatically generated index should be inserted. so -->
    <!-- if the index is completely empty, skip it. -->
  
    <xsl:if test="count(*)>0 or $generate.index != '0'">
      <div class="{name(.)}">
        <xsl:call-template name="component.separator"/>
        <xsl:choose>
          <xsl:when test="./title">
            <xsl:apply-templates select="./title" mode="component.title.mode"/>
          </xsl:when>
          <xsl:otherwise>
            <h2 class="title">
              <a>
                <xsl:attribute name="name">
                  <xsl:call-template name="object.id"/>
                </xsl:attribute>
                <xsl:call-template name="gentext.element.name"/>
              </a>
            </h2>
          </xsl:otherwise>
        </xsl:choose>
  
        <xsl:if test="./subtitle">
          <xsl:apply-templates select="./subtitle" mode="component.title.mode"/>
        </xsl:if>
  
        <xsl:apply-templates/>
  
        <xsl:if test="count(indexentry) = 0 and count(indexdiv) = 0">
          <xsl:call-template name="generate-index"/>
        </xsl:if>
  
        <xsl:call-template name="process.footnotes"/>
      </div>
    </xsl:if>
  </xsl:template>
  
  <xsl:template match="index/title"></xsl:template>
  <xsl:template match="index/subtitle"></xsl:template>
  <xsl:template match="index/titleabbrev"></xsl:template>
  
  <xsl:template match="index/title" mode="component.title.mode">
    <xsl:variable name="id">
      <xsl:call-template name="object.id">
        <xsl:with-param name="object" select=".."/>
      </xsl:call-template>
    </xsl:variable>
    <h2 class="title">
      <a name="{$id}">
        <xsl:apply-templates/>
      </a>
    </h2>
  </xsl:template>
  
  <xsl:template match="index/subtitle" mode="component.title.mode">
    <h3>
      <i><xsl:apply-templates/></i>
    </h3>
  </xsl:template>
  
  <!-- ==================================================================== -->
  
  <xsl:template match="indexdiv">
    <div class="{name(.)}">
      <xsl:apply-templates mode="not-indexentrys"/>
      <dl>
        <xsl:apply-templates select="indexentry"/>
      </dl>
    </div>
  </xsl:template>
  
  <xsl:template match="indexentry" mode="not-indexentrys">
    <!-- suppress -->
  </xsl:template>
  
  <xsl:template match="indexdiv/title">
    <xsl:variable name="id">
      <xsl:call-template name="object.id">
        <xsl:with-param name="object" select=".."/>
      </xsl:call-template>
    </xsl:variable>
    <h3 class="{name(.)}">
      <a name="{$id}">
        <xsl:apply-templates/>
      </a>
    </h3>
  </xsl:template>
  
  <!-- ==================================================================== -->
  
  <xsl:template match="indexterm">
    <xsl:variable name="id">
      <xsl:call-template name="object.id"/>
    </xsl:variable>
  
    <a class="indexterm" name="{$id}"/>
  </xsl:template>
  
  <xsl:template match="primary|secondary|tertiary|see|seealso">
  </xsl:template>
  
  <!-- ==================================================================== -->
  
  <xsl:template match="indexentry">
    <xsl:apply-templates select="primaryie"/>
  </xsl:template>
  
  <xsl:template match="primaryie">
    <dt>
      <xsl:apply-templates/>
    </dt>
    <xsl:choose>
      <xsl:when test="following-sibling::secondaryie">
        <dd>
          <dl>
            <xsl:apply-templates select="following-sibling::secondaryie"/>
          </dl>
        </dd>
      </xsl:when>
      <xsl:when test="following-sibling::seeie
                      |following-sibling::seealsoie">
        <dd>
          <dl>
            <xsl:apply-templates select="following-sibling::seeie
                                         |following-sibling::seealsoie"/>
          </dl>
        </dd>
      </xsl:when>
    </xsl:choose>
  </xsl:template>
  
  <xsl:template match="secondaryie">
    <dt>
      <xsl:apply-templates/>
    </dt>
    <xsl:choose>
      <xsl:when test="following-sibling::tertiaryie">
        <dd>
          <dl>
            <xsl:apply-templates select="following-sibling::tertiaryie"/>
          </dl>
        </dd>
      </xsl:when>
      <xsl:when test="following-sibling::seeie
                      |following-sibling::seealsoie">
        <dd>
          <dl>
            <xsl:apply-templates select="following-sibling::seeie
                                         |following-sibling::seealsoie"/>
          </dl>
        </dd>
      </xsl:when>
    </xsl:choose>
  </xsl:template>
  
  <xsl:template match="tertiaryie">
    <dt>
      <xsl:apply-templates/>
    </dt>
    <xsl:if test="following-sibling::seeie
                  |following-sibling::seealsoie">
      <dd>
        <dl>
          <xsl:apply-templates select="following-sibling::seeie
                                       |following-sibling::seealsoie"/>
        </dl>
      </dd>
    </xsl:if>
  </xsl:template>
  
  <xsl:template match="seeie|seealsoie">
    <dt>
      <xsl:apply-templates/>
    </dt>
  </xsl:template>
  
  <xsl:template name="generate-index">
    <!-- nop -->
  </xsl:template>
  
  </xsl:stylesheet>