configure.ac | 53 +++++-----------------------------------------
m4/libo_enable_vclplug.m4 | 27 +++++++++++++++++++++++
2 files changed, 33 insertions(+), 47 deletions(-)
New commits:
commit ee28a1464f2bbeaa24c34c73fee382f6e13a8ebb
Author: Jan-Marek Glogowski <glo...@fbihome.de>
AuthorDate: Mon Jan 3 13:10:48 2022 +0100
Commit: Jan-Marek Glogowski <glo...@fbihome.de>
CommitDate: Mon Jan 3 15:57:34 2022 +0100
Just ENABLE_* VCL plugins, if we test_* them
.. and move the code into a new m4 macro.
Writing the m4 macro turned out more complicated then expected,
because of the quoting needed to handle the unexpected argument
scope of AC_DEFUN.
Change-Id: I644a95e4a988f843d89713a0b544cafc79262adc
Reviewed-on: https://gerrit.libreoffice.org/c/core/+/127893
Tested-by: Jenkins
Reviewed-by: Jan-Marek Glogowski <glo...@fbihome.de>
diff --git a/configure.ac b/configure.ac
index e31f755866dd..595a0125e44b 100644
--- a/configure.ac
+++ b/configure.ac
@@ -11496,53 +11496,12 @@ if test "$USING_X11" != TRUE; then
enable_gtk3=no
fi
-ENABLE_GTK3=""
-if test "x$enable_gtk3" = "xyes"; then
- ENABLE_GTK3="TRUE"
- AC_DEFINE(ENABLE_GTK3)
- R="$R gtk3"
-fi
-AC_SUBST(ENABLE_GTK3)
-
-ENABLE_GTK3_KDE5=""
-if test "x$enable_gtk3_kde5" = "xyes"; then
- ENABLE_GTK3_KDE5="TRUE"
- AC_DEFINE(ENABLE_GTK3_KDE5)
- R="$R gtk3_kde5"
-fi
-AC_SUBST(ENABLE_GTK3_KDE5)
-
-ENABLE_GTK4=""
-if test "x$enable_gtk4" = "xyes"; then
- ENABLE_GTK4="TRUE"
- AC_DEFINE(ENABLE_GTK4)
- R="$R gtk4"
-fi
-AC_SUBST(ENABLE_GTK4)
-
-ENABLE_QT5=""
-if test "x$enable_qt5" = "xyes"; then
- ENABLE_QT5="TRUE"
- AC_DEFINE(ENABLE_QT5)
- R="$R qt5"
-fi
-AC_SUBST(ENABLE_QT5)
-
-ENABLE_QT6=""
-if test "x$enable_qt6" = "xyes"; then
- ENABLE_QT6="TRUE"
- AC_DEFINE(ENABLE_QT6)
- R="$R qt6"
-fi
-AC_SUBST(ENABLE_QT6)
-
-ENABLE_KF5=""
-if test "x$enable_kf5" = "xyes"; then
- ENABLE_KF5="TRUE"
- AC_DEFINE(ENABLE_KF5)
- R="$R kf5"
-fi
-AC_SUBST(ENABLE_KF5)
+libo_ENABLE_VCLPLUG([gtk3])
+libo_ENABLE_VCLPLUG([gtk3_kde5])
+libo_ENABLE_VCLPLUG([gtk4])
+libo_ENABLE_VCLPLUG([qt5])
+libo_ENABLE_VCLPLUG([qt6])
+libo_ENABLE_VCLPLUG([kf5])
if test "x$USING_X11" = "xyes"; then
R="$R gen"
diff --git a/m4/libo_enable_vclplug.m4 b/m4/libo_enable_vclplug.m4
new file mode 100644
index 000000000000..89b065f8fcc6
--- /dev/null
+++ b/m4/libo_enable_vclplug.m4
@@ -0,0 +1,27 @@
+dnl -*- Mode: Autoconf; tab-width: 4; indent-tabs-mode: nil; fill-column: 102
-*-
+#
+# This file is part of the LibreOffice project.
+#
+# This Source Code Form is subject to the terms of the Mozilla Public
+# License, v. 2.0. If a copy of the MPL was not distributed with this
+# file, You can obtain one at http://mozilla.org/MPL/2.0/.
+#
+AC_DEFUN([libo_ENABLE_VCLPLUG],[
+dnl The $1 of enable_var is taken from the libo_ENABLE_VCLPLUG, so concat
+dnl needs extra quoting and enable_var has no "magic" argument.
+m4_pushdef([concat],[$][1][$][2])
+m4_pushdef([enable_var],[concat(ENABLE_,m4_toupper($1))])
+
+enable_var=
+if test "$test_$1" != no -a "$enable_$1" = yes; then
+ enable_var=TRUE
+ AC_DEFINE(enable_var)
+ R="$R $1"
+fi
+AC_SUBST(enable_var)
+
+m4_popdef([enable_var])
+m4_popdef([concat])
+])
+
+dnl vim:set shiftwidth=4 softtabstop=4 expandtab:
