Re: [Programmer-VB] listbox ascending

[Aris Rismayana]

Mudah2an ini yg dimaksud..
Cuman copas dari sebuah sumber..



Menyortir Data di ListBox dan ComboBox

'Deskripsi: Menyortir data di ListBox dan ComboBox secara ASCENDING
'           Jika Anda menempatkan data: File1.gif, File2.gif, File3.gif dan
'           File10.gif ke dalam listbox atau combobox lalu menset
'           property Sorted = True, maka hasilnya akan menjadi
'           File1.gif
'           File10.gif
'           File2.gif
'           File3.gif
'           Program berikut ini akan menyortirnya menjadi seperti ini:

'           File1.gif
'           File2.gif
'           File3.gif
'           File10.gif
'Persiapan: 1. Buat 1 Project baru dengan 1 Form, 1 ListBox, 1
ComboBox, dan 2 Commandbutton.
'           2. Copy-kan coding berikut ke dalam editor form yang bertalian.
'--------------------------------------------------------------------------------------------

Sub ReSort(L As Control)       'Fungsi untuk menyortir data
  Dim P%, PP%, C%, Pre$, S$, V&, NewPos%, CheckIt%
  Dim TempL$, TempItemData&, S1$


  For P = 0 To L.ListCount - 1
    S = L.List(P)
    For C = 1 To Len(S)
        V = Val(Mid$(S, C))
        If V > 0 Then Exit For
    Next
    If V > 0 Then
        If C > 1 Then Pre = left$(S, C - 1)
        NewPos = -1
        For PP = P + 1 To L.ListCount - 1
            CheckIt = False
            S1 = L.List(PP)
            If Pre <> "" Then
                If InStr(S1, Pre) = 1 Then CheckIt = True
            Else
                If Val(S1) > 0 Then CheckIt = True

            End If
            If CheckIt Then
                If Val(Mid$(S1, C)) < V Then NewPos = PP
            Else
                Exit For
            End If
        Next
        If NewPos > -1 Then
            TempL = L.List(P)
            TempItemData = L.ItemData(P)
            L.RemoveItem (P)
            L.AddItem TempL, NewPos
            L.ItemData(L.NewIndex) = TempItemData
            P = P - 1
        End If
    End If
  Next
  Exit Sub
End Sub

Private Sub Command1_Click()
   Call ReSort(List1)  'Sortir data di listbox
End Sub

Private Sub Command2_Click()
   Call ReSort(Combo1)  'Sortir data di combobox
End Sub

Private Sub Form_Load()
    'Tambahkan item data ke dalam listbox
    List1.AddItem "File3.gif"
    List1.AddItem "File2.gif"
    List1.AddItem "File10.gif"
    List1.AddItem "File1.gif"
    'Tambahkan item data ke dalam combobox
    Combo1.AddItem "File3.gif"
    Combo1.AddItem "File2.gif"

    Combo1.AddItem "File10.gif"
    Combo1.AddItem "File1.gif"
End Sub