[gentoo-commits] gentoo-x86 commit in x11-drivers/xf86-video-intel: xf86-video-intel-2.99.917-r2.ebuild ChangeLog

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    15/06/15 12:26:19

  Modified:             ChangeLog
  Added:                xf86-video-intel-2.99.917-r2.ebuild
  Log:
  Add patch to fix SNA crash with newer libdrm/kernel, bug #552124.
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 
0x2324E7B566DF2611!)

Revision  Changes    Path
1.170                x11-drivers/xf86-video-intel/ChangeLog

file : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-drivers/xf86-video-intel/ChangeLog?rev=1.170&view=markup
plain: 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-drivers/xf86-video-intel/ChangeLog?rev=1.170&content-type=text/plain
diff : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-drivers/xf86-video-intel/ChangeLog?r1=1.169&r2=1.170

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-drivers/xf86-video-intel/ChangeLog,v
retrieving revision 1.169
retrieving revision 1.170
diff -u -r1.169 -r1.170
--- ChangeLog   13 Jun 2015 22:53:00 -0000      1.169
+++ ChangeLog   15 Jun 2015 12:26:19 -0000      1.170
@@ -1,6 +1,13 @@
 # ChangeLog for x11-drivers/xf86-video-intel
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-drivers/xf86-video-intel/ChangeLog,v 
1.169 2015/06/13 22:53:00 chithanh Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-drivers/xf86-video-intel/ChangeLog,v 
1.170 2015/06/15 12:26:19 chithanh Exp $
+
+*xf86-video-intel-2.99.917-r2 (15 Jun 2015)
+
+  15 Jun 2015; Chí-Thanh Christopher Nguyễn <chith...@gentoo.org>
+  +files/xf86-video-intel-2.99.917-libdrm-kernel-4_0-crash.patch,
+  +xf86-video-intel-2.99.917-r2.ebuild:
+  Add patch to fix SNA crash with newer libdrm/kernel, bug #552124.
 
 *xf86-video-intel-2.99.917-r1 (13 Jun 2015)
 



1.1                  
x11-drivers/xf86-video-intel/xf86-video-intel-2.99.917-r2.ebuild

file : 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-drivers/xf86-video-intel/xf86-video-intel-2.99.917-r2.ebuild?rev=1.1&view=markup
plain: 
http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-drivers/xf86-video-intel/xf86-video-intel-2.99.917-r2.ebuild?rev=1.1&content-type=text/plain

Index: xf86-video-intel-2.99.917-r2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: 
/var/cvsroot/gentoo-x86/x11-drivers/xf86-video-intel/xf86-video-intel-2.99.917-r2.ebuild,v
 1.1 2015/06/15 12:26:19 chithanh Exp $

EAPI=5

XORG_DRI=dri
inherit linux-info xorg-2

DESCRIPTION="X.Org driver for Intel cards"

KEYWORDS="~amd64 ~x86 ~amd64-fbsd -x86-fbsd"
IUSE="debug +sna +udev uxa xvmc"

REQUIRED_USE="
        || ( sna uxa )
"

RDEPEND="x11-libs/libXext
        x11-libs/libXfixes
        >=x11-libs/pixman-0.27.1
        >=x11-libs/libdrm-2.4.29[video_cards_intel]
        sna? (
                >=x11-base/xorg-server-1.10
        )
        udev? (
                virtual/udev
        )
        xvmc? (
                x11-libs/libXvMC
                >=x11-libs/libxcb-1.5
                x11-libs/xcb-util
        )
"
DEPEND="${RDEPEND}
        >=x11-proto/dri2proto-2.6
        x11-proto/dri3proto
        x11-proto/presentproto
        x11-proto/resourceproto"

PATCHES=(
        "${FILESDIR}"/${P}-sna-udev-fstat.patch
        "${FILESDIR}"/${P}-uxa-udev-fstat.patch
        "${FILESDIR}"/${P}-libdrm-kernel-4_0-crash.patch
)

src_configure() {
        XORG_CONFIGURE_OPTIONS=(
                $(use_enable debug)
                $(use_enable dri)
                $(use_enable sna)
                $(use_enable uxa)
                $(use_enable udev)
                $(use_enable xvmc)
                --disable-dri3
        )
        xorg-2_src_configure
}

pkg_postinst() {
        if linux_config_exists \
                && ! linux_chkconfig_present DRM_I915_KMS; then
                echo
                ewarn "This driver requires KMS support in your kernel"
                ewarn "  Device Drivers --->"
                ewarn "    Graphics support --->"
                ewarn "      Direct Rendering Manager (XFree86 4.1.0 and higher 
DRI support)  --->"
                ewarn "      <*>   Intel 830M, 845G, 852GM, 855GM, 865G (i915 
driver)  --->"
                ewarn "       i915 driver"
                ewarn "      [*]       Enable modesetting on intel by default"
                echo
        fi
}