> On Mar 20, 2024, at 8:14 PM, Pål Baggethun <[email protected]> wrote:
>
> What happened to the "Record Starts" checkbox in the Analyze Particles
> dialog? I could not find any mention of this being removed in the release
> notes.
The “Record starts” checkbox has been replaced by “Overlay” but macros that use
the ‘record’ keyword continue to work.
Here is an updated version of the CircularParticles macro linked to in the
ImageJ User Guide that uses ‘overlay’ instead of ‘record’:
// This macro demonstrates how to erase non-circular objects
run("Blobs (25K)");
setThreshold(125, 248);
run("Set Measurements...", "area perimeter circularity decimal=3");
run("Analyze Particles...", "clear overlay");
for (i=0; i<nResults; i++) {
circularity = getResult('Circ.', i);
if (circularity<0.85) {
Overlay.activateSelection(i);
run("Clear");
}
}
run("Select None");
exit;
// Original version that uses "Record starts"
run("Select None");
requires("1.29n");
run("Blobs (25K)");
setThreshold(125, 248);
run("Set Measurements...", "area perimeter circularity decimal=3");
run("Analyze Particles...", "minimum=1 maximum=999999 bins=20 show=Nothing
clear record");
for (i=0; i<nResults; i++) {
x = getResult('XStart', i);
y = getResult('YStart', i);
circularity = getResult('Circ.', i);
if (circularity<0.85) {
doWand(x,y);
run("Clear");
}
}
run("Select None");
--
ImageJ mailing list: http://imagej.nih.gov/ij/list.html
